>　確認したところ、<MenuBar2> <popup>と書かれていましたが、

これはメニューの左から二つめのどこかと、右クリックメニューのどこかに
この機能が登録されているということです。たぶんメニューの「編集」-「変換」
あたりと、選択範囲がある状態での右クリックメニューの「変換」の下に
あるのでは……。このへんには他にもいろいろ便利な変換があります。

>大抵はカッコ（「　」）でくくっています（以下の例）。

ちょこっとマクロ作ってみました。わたしにも作れそうなものは限られていますが。
それに気が向かないと作りませんので、そのへんはお気遣いなく。

'カッコの中だけカタカナ変換

proc main
	const head$ = "「『" '前方カッコの定義・何個でも（ペア判断なし）
	const tail$ = "」』" '後方カッコの定義・何個でも
	dim i
	@UndoBlock = 1
	i = @BytePosCr 'カーソル位置記憶
	do while 1 'カーソルが前方カッコにくるまで繰返す
		@MoveLeftChar
		if instr(head$, chr$(@Code)) > 0 then exit do
		'行の先頭（ファイル先頭含む）まで来てしまったら中止
		if @BytePosCr = 1 then
			@BytePosCr = i
			print "前方カッコがありません" 'ステータスバーにエラーメッセージ
			exit proc
		end if
	loop
	@BlockSelect '選択開始
	@BytePosCr = i 'さっきのカーソル位置までもどる
	do while 1 'カーソルが後方カッコにくるまで繰返す
		@MoveRightChar
		'カッコより先に改行かファイル末尾に遭遇したら中止
		if @Code = CODE_RETURN or @Code = CODE_EOF then
			@BlockSelect '選択解除
			@BytePosCr = i
			print "後方カッコがありません" 'ステータスバーにエラーメッセージ
			exit proc
		end if
		if instr(tail$, chr$(@Code)) > 0 then exit do
	loop
	@BlockToKatakana '選択範囲をカタカナ変換 + 選択解除
	@BytePosCr = i '最初の位置にカーソルもどす
	@UndoBlock = 0
end proc